Sitenotice: 11/29/2018: The wiki is back. It turns out, some anti-virus product on my web server had an issue with the latest version of PHP. My server techs have resolved this issue, and things should be working again. During the investigation, I did restore to a backup from September. There is a chance that any changes done since then were lost, but I do not recall any edits. --OS-9 Al

8/30/2016: Massive re-work is being done on the InfoBox Templates. Read that page to keep up with the plan for that, and adding better keyword tags (categories) to all the pages. --OS-9 Al (talk) 15:28, 31 August 2016 (CDT)

Helicopter battleground for you

From CoCopedia - The Tandy/Radio Shack Color Computer Wiki
Jump to navigation Jump to search
WELCOME
Looking for CoCo help? If you are trying to do something with your old Color Computer, read this quick reference. Want to contribute to this wiki? Be sure to read this first. This CoCo wiki project was started on October 29, 2004. --OS-9 Al

See Recent Changes. | About this site. | Join the E-Mail List, Facebook Group or Google+ | Contact me with updates/questions.

This page was last updated on 05/3/2019. Total Pages: 647. Total Files: 937.


Home / Publications / Rainbow / Rainbow 1981 / Rainbow 1981-10 - Helicopter battleground for you


If you enjoyed fighting around the LASER STAR last month, JARB SOFTWARE offers another sample goodie for your joysticking pleasure this month as well.

This is HELO BATTLE, which pits you against a fortified castle that shoots antiaircraft rounds at your helicopter.

To play, you have to fly your chopper to avoid the incoming fire while, at the same time, aiming and firing your gun.

The right joystick controls the copter's flight and the left the chopper's gun. Obviously, there is some eye-hand coordination necessary here! At the end of the game, your friendly COLOR Computer will let you know who won the encounter -- and will give you the option of playing again.

You can purchase HELD BATTLE on a tape with LASER STAR by sending $14.95 to JARB SOFTWARE, 1169 Florida St., Imperial Beach, CA, 92032. Please add $1 for postage and handling.

Oh...watch out for the sneaky little guy!

The Listing:


1 '**************************
2 '*        HELO-BATTLE     *
3 '*            by          *
4 '*     JARB SOFTWARE      *
5 '* (c) JARB SOFTWARE 1981 *
6 '**************************
10 CLS:PRINT@192,TAB(10)"HELO BATTLE":PRINTTAB(15)"BY":PRINTTAB(9)"JARB SOFTWARE":FORI=1TO5:PLAY"O"+STR$(I)+"V30T16L4EP8EP8EP8L1AP8EP2L4BGGEADEADDDP4":NEXTI
15 CLEAR200
20 DIMA (30, 30)
25 ALLIES=ALLIES+OS:AXIS=AXIS+TS:OS=0:TS=0
30 IF ALLIES>=200 THEN 225
35 IF AXIS>=200 THEN 225
40 S$="V30T100L64O1DD"
45 PMODE4,1:PCLS:SCREEN 1,1:A=128:B=24:A1=128:B1=96
50 T1=RND(195)+30:T2=T1
55 A$="BU20L10D10L1DE10BG10G4D4F4R20BU22R2U2L2U4R2U2L60R122L60D2R2D4L2D2R10F8R60E8BD4H10BF10F10BH10G10BE10E10BG10BU4R4D10L72G12L10BR5D5R20BL20L15U5BD5L20H5"
60 B$="BL25U20R5D5BD3D4R5U4L5BU3R5U5R5D10R20U10R5D5BD3D4R5U4L5BU3R5U5R5D20"
65 DRAW"S1BM128,28"+A$
70 GET(102,16)-(158,33),A,G
75 PCLS
80 DRAW"S3;BM"+STR$(T1)+",191"+B$:PAINT(T1,191)
85 HEIGHT=RND(191)
90 PUT(A-26,B-14)-(A+30,B+7), A,PSET
95 IF HEIGHT<=19 THEN 85
100 IF HEIGHT>=170 THEN 85
105 DRIFT=RND(32)-16
110 ES=ES+1:SOUND1,1:FORI=1TO3:CIRCLE(T1,176),I,1:NEXTI:FORI=1TO3:CIRCLE(T1,176),I,0:NEXTI
115 FOR FLAK=176 TO HEIGHT STEP-10:T1=T1+DRIFT:A1=JOYSTK(2)*4:A=A+INT(JOYSTK(0)/6.3)-5:B=B+INT(JOYSTK(1)/6.3)-5:PSET(T1,FLAK,1)
120 IFPPOINT(T2,189)=0 THEN 205
125 IFA<=28 THEN A=28
130 IFT1<=20 THEN 175
135 IFT1>=235 THEN 175
140 IFA>=225 THEN A=225
145 IFB<=24 THEN B=24
150 IFB>=171 THEN B=171
155 IFB=171 THEN 210
160 PUT(A-26,B-14)-(A+30,B+7),A,PSET:PLAYS$:IFPEEK(65280)=125ORPEEK(65280)=253GOTO195
165 PRESET(T1,FLAK)
170 NEXT FLAK
175 PLAY"O1V30T32L32BBB":FORI=1TO10:CIRCLE(T1,FLAK),I,1:NEXTI
180 E1=PPOINT(A-15,B):F1=PPOINT(A-17,B):E2=PPOINT(A+25,B):F2=PPOINT(A+23,B): E3=PPOINT(A,B-15):F3=PPOINT(A,B-13):E4=PPOINT(A,B+8):F4=PPOINT(A,B+10)
185 IF E1<>0 AND F1<>0 OR E2<>0 AND F2<>0 OR E3<>0 AND F3<>0 OR E4<>0 AND F4<>0 THEN 200
190 FORI=1TO10:CIRCLE(T1,FLAK),I,0:NEXTI:T1=T2:GOTO85
195 SF=SF+1:LINE(A,B-3)-(A1,191),PSET:CIRCLE(A1,191),2:PLAY"O1V30Tl00L64DF2DP2DP2DP2DP2D":LINE(A,B-3)-(A1,191),PRESET: FORI=1TO2:CIRCLE(A1,169),I,0:NEXTI:GOTO165
200 TS=10:FORI=1TO40STEP2:Z1=RND(255):Z2=RND(191):LINE(A,B-7)-(Z1,Z2),PSET:CIRCLE(Z1,Z2),2:CIRCLE(A,B-7),I/2: PLAY"OlV30T100L100DDV10DD":NEXTI:GOTO25
205 OS=10:FORI=lTO40:CIRCLE(T2,191),I,1,1.5,.5,0: PLAY"01V30T100DV20DV10D":NEXTI:GOTO25
210 T3=RND(255):DRAW"S4;BM"+STR$(T3)+",191E3F3BH3U4L1U1R2D1L1D2L3BR3R3":PLAY"O4T32V30L8AEP1DFGBP1AAEDCP1FP1FP1BP1BP1D1DP1DF1DP1":FORI=1TO100:NEXTI:LINE(T3,185)-(A,B-7),PSET:PLAY"O1V30T100L64DP2DP2DP2DP2DP2DP2DP2DP2DP2":LINE(T3,185)-(A,B-7),PSET
225 SCREEN0,1:CLS:FORI=1TO10:CLSRND(8):SOUNDI*10,I:NEXTI
230 CLS0:PRINT@64,STRING$(10,128);:PRINT"FINAL SCORES ",:PRINTSTRING$(8,128);
235 PRINT@192,TAB(10)"YOUR SCORE=";ALLIES*5:PRINTTAB(10)"TOTAL SHOTS=";SF
240 PRINTSTRING$(32,126);
245 PRINTTAB(10)"ENEMY SCORE=";AXIS*5:PRINTTAB(10)"TOTAL SHOTS=";ES
250 PRINTSTRING$(32,128);
255 IF ALLIES>AXIS THEN 275
260 IF ALLIES<AXIS THEN 280
265 IF ALLIES=AXIS THEN 285
270 GOTO235
275 PRINT"       YOU HAYE WON THIS BATTLE":GOTO290
280 PRINT" THE ENEMY HAS WON THIS BATTLE":GOTO290
285 PRINT" THIS BATTLE IS DECLARED A TIE":GOTO290
290 PRINTSTRING$(32,128);:PRINT"DO YOU WISH TO PLAY AGAIN (Y/N)?";
295 PA$=INKEY$:IFPA$=""THEN295
300 IFPA$<>"Y"THENEND
305 GOTO15

Links

See this article as it appeared in the magazine, in Archive.org